Active Filter Noise Study

An often used active filter is a second order Butterworth realized using the Sallen and Key circuit. There are several sources on the net for designs of Sallen and Key filters, including the ECircuit Center. The ECircuit page provides a SPICE file for the filter design which is reproduced here:
OPSALKEY1.CIR - OPAMP SALLEN-KEY LOW-PASS FILTER
* 2ND-ORDER BUTTERWORTH
*
VS	1	0	AC	1
*
R1	1	2	11.2K
R2	2	3	11.2K
C1	2	5	2000PF
C2	3	0	1000PF
*
* UNITY GAIN AMPLIFIER, RA=OPEN, RB=SHORT
RA	4	0	100MEG
RB	4	5	1
XOP	3 4	5	OPAMP1
*
* SINGLE RC FILTER FOR COMPARISON
R10	1	10	15.9K
C10	10	0	1000PF
*
* OPAMP MACRO MODEL, SINGLE-POLE 
* connections:      non-inverting input
*                   |   inverting input
*                   |   |   output
*                   |   |   |
.SUBCKT OPAMP1      1   2   6
* INPUT IMPEDANCE
RIN	1	2	10MEG
* DC GAIN (100K) AND POLE 1 (100HZ)
* GBWP = 10MHz
EGAIN   3 0     1 2     100K
RP1     3       4       1K
CP1     4       0       1.5915UF
* OUTPUT BUFFER AND RESISTANCE
EBUFFER 5 0     4 0     1
ROUT    5       6       10
.ENDS
* 
* ANALYSIS
.AC 	DEC 	10 100 1MEG
* VIEW RESULTS
.PLOT	AC 	V(5)
.PROBE
.END
The Sallen and Key SPICE input file is readily converted to the corresponding CCICAP input file. Here we also add a noise analysis and create a Noise Table from the results:
.title OPSALKEY1.CIR - OPAMP SALLEN-KEY LOW-PASS FILTER
* 2ND-ORDER BUTTERWORTH
*
.opt txt
.include op27.mdl
.ac 20 10 10. 1.MEG
.plot ac png eout eout >
.plot ac png erc erc >
.plot ac png eout erc NDM INM

' noise from all elements
.noise

.plot ac png NDM INM

'integrated (total) noise table
.n_table inte 20

.ckt
v ein 1 0 1.
*
r R1	1	2	11.2K
r R2	2	3	11.2K
c C1	2	5	2000.PF
c C2	3	0	1000.PF
*
* UNITY GAIN AMPLIFIER,
oa a1 3 5 5 op27

* SINGLE RC FILTER FOR COMPARISON
r R10 1 10 15.9K
c C10 10 0 1000.PF
*
vm eout 5 0
vm erc 10 0
.END
.go
.stop
The response plot from the filter (dB and phase) and a plot of both spot (NDM) and total noise (INM) from the CCICAP run are shown here:
Filter AC and Noise ResponsesFilter AC and Noise Responses
The noise table details the sources of noise in the circuit at the requested frequencies. Note that the op-amp dominates at very low frequencies due to the 1/f noise, but the resistors eventually produce most of the noise in the circuit.
 OPSALKEY1.CIR - OPAMP SALLEN-KEY LOW-PASS FILTER                              
 Component Integrated Noise Table
 Noise data at T = 2.982E+02 K

 Frequency, total spot noise, total integrated noise: 
     1.0E+01  4.0E-08  0.0E+00
 Component integrated noise table:
   R1        0.000E+00   R2        0.000E+00   a1        0.000E+00
   R10       0.000E+00

 Frequency, total spot noise, total integrated noise: 
     1.0E+02  2.4E-08  2.6E-07
 Component integrated noise table:
   a1        1.845E-07   R2        1.288E-07   R1        1.288E-07
   R10       0.000E+00

 Frequency, total spot noise, total integrated noise: 
     1.0E+03  2.2E-08  7.1E-07
 Component integrated noise table:
   R2        4.286E-07   R1        4.272E-07   a1        3.752E-07
   R10       0.000E+00

 Frequency, total spot noise, total integrated noise: 
     1.0E+04  2.2E-08  2.3E-06
 Component integrated noise table:
   R2        1.579E-06   R1        1.265E-06   a1        1.046E-06
   R10       0.000E+00

 Frequency, total spot noise, total integrated noise: 
     1.0E+05  3.7E-09  3.3E-06
 Component integrated noise table:
   R2        2.409E-06   a1        1.684E-06   R1        1.435E-06
   R10       0.000E+00

 Frequency, total spot noise, total integrated noise: 
     1.0E+06  3.0E-09  4.4E-06
 Component integrated noise table:
   a1        3.320E-06   R2        2.479E-06   R1        1.435E-06
   R10       0.000E+00